単一項目サーチ

• ウィキデータの非推奨の理由の一覧 Q52105174

条件付き検索

https://www.wikidata.org/w/index.php?title=Special:Search

綾瀬市にある都市公園

haswbstatement:P131=Q792819 haswbstatement:P31=Q108804646

* P131=Q792819    綾瀬市
* P31=Q108804646    都市公園

綾瀬市にあるWikidata項目（地名を除く）

haswbstatement:P131=Q792819 -haswbstatement:P31=Q486972|Q5327369

- P131=Q792819    綾瀬市
- -P31=Q486972|Q5327369    地名をのぞく

Wikidata Query Service

「Wikidata Query Service 」https://query.wikidata.org/ を使った検索例

「オープンストリートマップのキーまたはタグ」を持つもの

SELECT ?item ?itemLabel ?osm_tag
WHERE
{
  ?item wdt:P1282 ?osm_tag.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}

「オープンストリートマップのキー Key:religion(宗教) 」を持つもの

SELECT ?item ?itemLabel ?osm_tag
WHERE
{
  ?item wdt:P1282 'Key:religion'.
  OPTIONAL {
    ?item wdt:P1282 ?osm_tag.
  } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}

「案内標識」に分類されているもの

• 「日本」にある
• 「案内標識」に、分類または子項目になっているもの

SELECT ?item ?itemLabel ?propLabel ?position
WHERE
{
  ?item wdt:P17 wd:Q17;                # 「日本」にある
        wdt:P31/wdt:P279* wd:Q6031215. # 「案内標識」に分類されているもの
  OPTIONAL {
    ?item wdt:P625 ?position.   # 位置座標
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}

公園に分類されているもの

綾瀬市にある「公園」の一覧

• 綾瀬市 ... 位置する行政区画:P131 = 綾瀬市:Q792819
• 公園 ... 再帰:{分類:P31 または 上位クラス:P279} = 公園:Q22698

SELECT ?park ?parkLabel ?propLabel ?position
WHERE
{
  ?park wdt:P131 wd:Q792819;
        wdt:P31/wdt:P279* wd:Q22698. # 公園に分類されているもの
  OPTIONAL {
    ?park wdt:P361 ?prop.   # 綾瀬市の公園
    ?park wdt:P625 ?position.   # 位置座標
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}

海老名市の地図

「海老名市」にある「位置情報:P625」を持つ項目

• 海老名市 ... 位置する行政区画:P131 = 海老名市:Q734390

SELECT DISTINCT ?geo ?item ?itemLabel ?image WHERE {
  ?item wdt:P131 wd:Q734390;        # 海老名市にある
        wdt:P625 ?geo .
  OPTIONAL {
    ?item wdt:P18 ?image.
  }  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}